home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Aminet 5
/
Aminet 5 - March 1995.iso
/
Aminet
/
util
/
misc
/
ftrans12.lha
/
FTCed.ced
< prev
next >
Wrap
Text File
|
1994-04-22
|
3KB
|
95 lines
/* $VER: FTCed.ced 1.0 (Mar 24 1994)
*
* FTrans-CygnusEd ARexx-Script (c) Copyright 1994 by Rainer Hess
*
* Jan 8 1994 - Jan 10 1994 - Jan 12 1994 - Mar 24 1994
*/
options results
CR = '0A'X /* Carrige Return */
BLOCKFILE = 't:FTransWort' /* Dateiname für Austausch festlegen */
/*
* rexxcedsupport.library einbinden.
*/
if ~show('l',"rexxcedsupport.library") then do
call addlib 'rexxcedsupport.library',0,-30,0
if (result = 0) then do
okay1 "Die rexxcedsupport.library kann nicht eingebunden werden!" CR || "Evtl. ist die rexxcedsupport.library nicht installiert..."
exit
end
end
/* --- ob FTrans aktiv ---*/
if ~show( 'p', 'rexx_FTrans' ) then do
okay1 "Oops! FTrans ist nicht aktiv." CR || "Bitte FTrans aktivieren..."
exit
end
/* --- CygnusEd --- */
on = 0 /* Merker vorbesetzen */
address 'rexx_ced' /* CygnusEd Arexx-Port suchen */
status 11 /* Layout Abfragen */
if( result = 1) then do /* Wenn Layout ein dann ausschalten! */
layout /* Layout macht Probleme beim Zeilenende */
on = 1 /* Merken ob Layout ein war */
end
status 82 /* Datei editierbar ? */
if( result = 0) then do
okay1 "Datei ist nicht editierbar! Falls dies" CR || "doch erwünscht ist, CygnusEd auf Datei" CR || "editieren umschalten..."
exit
end
if( open(outfile,BLOCKFILE,'W') = 0) then do
okay1 "Die Übergabedatei """BLOCKFILE""" ist " CR || "nicht zu öffnen! Abbruch..."
exit
end
cedwort = csGetWord() /* Wort unter Cursor von CygnusEd abholen */
writech(outfile, cedwort ) /* Wort in Übergabedatei speichern */
close(outfile) /* Übergabedatei schließen */
csdelword()
/* --- FTRANS --- */
address 'rexx_FTrans' /* FTrans Arexx-Port suchen */
FTEcho "off" /* FTransARexx-Echo auschalten */
message "Melde FTEcho ist:", /* Dies auf FTrans-Ausgabeschirm mitteilen */
result
OldPublicScreen /* Alten PublicScreen abfragen */
oldpubscr = result /* Alten PublicScreen merken */
PublicScreen "CygnusEdScreen1" /* LernWindow auf Ced-Screen umschalten */
/* Nur möglich ab Kickstart 2.x und wenn */
/* CygnusEd als PublicScreen läuft. */
Wort BLOCKFILE /* FTrans auf Wortübersetzung umschalten */
/* Dateiname in mit WORT in BLOCKFILE. */
PublicScreen oldpubscr /* LernWindow auf vorherigen PublicScreen */
/* zurückschalten */
/* --- CygnusEd --- */
address 'rexx_ced' /* CygnusEd Arexx-Port suchen */
include file BLOCKFILE /* Block wieder einfügen, evtl. übersetzt */
if( on = 1 ) then do /* Layout war eingeschaltet, */
layout /* dann wieder aktivieren */
end
address command 'c:delete >NIL:' BLOCKFILE /* Austauschdatei löschen */
exit 0